home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Gold Collection
/
Software Vault - The Gold Collection (American Databankers) (1993).ISO
/
cdr26
/
dos60sup.zip
/
SETUP.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-04-05
|
7KB
|
283 lines
@echo off
if "%2"=="COPY" goto docopy
echo.
echo Installs the utilities on the MS-DOS 6 Supplemental disks, including:
echo * AccessDOS - assists persons with disabilities in using MS-DOS 6.
echo * Keyboard utilities, including Dvorak keyboard layouts.
echo * A program for creating a bootable compressed floppy disk.
echo * Utilities from MS-DOS 5.0 that were not included with MS-DOS 6.
echo * Updated network files for MS-DOS 6.
echo.
if "%1"=="" goto usage
if not exist DISKID01.BAT goto direrr
echo Do you wish to install:
echo.
echo A: All the components (requires about 830K of free disk space)
echo S: Selected components only
echo X: Exit
echo.
choice /c:asx "All, Selected, Exit "
if errorlevel 3 goto done
set SD6=S
if not "%SD6%"=="S" goto enverr
if errorlevel 2 goto checkdir
set SD6=A
:checkdir
echo.
expand diskid01.bat %1\amjklfgh.000 > NUL
if exist %1\amjklfgh.000 goto package1
echo The directory %1 does not exist.
echo Do you wish to create this directory?
choice /c:yx "Yes, Exit "
if errorlevel 2 goto done
echo Creating directory %1.
md %1
expand diskid01.bat %1\amjklfgh.000 > NUL
if not exist %1\amjklfgh.000 goto patherr
:package1
if "%SD6%"=="A" goto auto1
echo.
echo.
echo AccessDOS
echo =========
echo AccessDOS is a package of MS-DOS extensions that provide users who
echo are movement or hearing disabled with better access to computers
echo that run MS-DOS 6. AccessDOS requires about 270K of free disk space.
echo.
echo Do you wish to copy the AccessDOS utilities?
choice /c:ynx "Yes, No, Exit "
echo.
if errorlevel 3 goto done
if errorlevel 2 goto package2
:auto1
echo TAG > %1\amjklfgh.001
:package2
if "%SD6%"=="A" goto auto2
echo.
echo Keyboard Utilities
echo ==================
echo This package includes three Dvorak keyboard layouts, which can be used
echo with any standard keyboard. These layouts are specifically designed to
echo help individuals who type with a single hand or who have difficulty
echo with the standard QWERTY layout.
echo.
echo The package also includes KBDBUF.SYS, which allows you to increase your
echo keyboard type-ahead buffer.
echo.
echo This package requires about 25K of free disk space.
echo.
echo Do you wish to copy the keyboard utilities?
choice /c:ynx "Yes, No, Exit "
echo.
if errorlevel 3 goto done
if errorlevel 2 goto package3
:auto2
echo TAG > %1\amjklfgh.002
:package3
if "%SD6%"=="A" goto auto3
echo.
echo Creating a Bootable Compressed Floppy Disk
echo ==========================================
echo The DBLBOOT.BAT program creates a bootable compressed floppy disk. This
echo program requires about 20K of free disk space.
echo.
echo Do you wish to copy this program?
choice /c:ynx "Yes, No, Exit "
echo.
if errorlevel 3 goto done
if errorlevel 2 goto package4
:auto3
echo TAG > %1\amjklfgh.003
:package4
if "%SD6%"=="A" goto auto4
echo.
echo Additional MS-DOS Utilites
echo ==========================
echo This package contains utilities from MS-DOS 5.0 that were not included
echo with MS-DOS 6. This package requires about 290K of free disk space.
echo.
echo Do you wish to copy these utiliies?
choice /c:ynx "Yes, No, Exit "
echo.
if errorlevel 3 goto done
if errorlevel 2 goto package5
echo.
:auto4
echo TAG > %1\amjklfgh.004
:package5
if "%SD6%"=="A" goto auto5
echo.
echo MS-DOS 6 Network Files
echo ======================
echo If you upgraded to MS-DOS 6 from a version of MS-DOS less than 5.0, you
echo might need to update your network files. This package contains
echo the networks files that will work with MS-DOS 6. The package requires
echo about 275K of free disk space.
echo.
echo Do you wish to copy the network files?
choice /c:ynx "Yes, No, Exit "
echo.
if errorlevel 3 goto done
if errorlevel 2 goto copyit
echo.
:auto5
echo TAG > %1\amjklfgh.005
:copyit
if not exist %1\amjklfgh.00? goto done
echo.
echo Please Wait...
if not exist %1\choice.com copy choice.com %1 > NUL
copy sd6copy.bat %1 > NUL
if exist %1\expand.exe ren %1\expand.exe expand.999 > NUL
copy expand.exe %1 > NUL
copy setup.bat %1\sd6setup.bat > NUL
%1\sd6setup %1 COPY
:docopy
set SD6=1
echo.
echo Copying Supplemental Utilities...
echo ---------------------------------------
if not exist %1\amjklfgh.001 goto copy2
call %1\sd6copy ADOS.OVL %1
call %1\sd6copy ADOS.COM %1
call %1\sd6copy ADOS.CFG %1
call %1\sd6copy ADOS.TXT %1
call %1\sd6copy AREADME.TXT %1
call %1\sd6copy FAKEMOUS.COM %1
:copy2
if not exist %1\amjklfgh.002 goto copy3
call %1\sd6copy DVORAK.SYS %1
call %1\sd6copy DVORAK.TXT %1
call %1\sd6copy KBDBUF.SYS %1
:copy3
if not exist %1\amjklfgh.003 goto copy4
call %1\sd6copy DBLBOOT.BAT %1
call %1\sd6copy DBLBOOT.INI %1
:copy4
if not exist %1\amjklfgh.004 goto copy5
call %1\sd6copy ASSIGN.COM %1 D
call %1\sd6copy BACKUP.EXE %1 D
call %1\sd6copy COMP.EXE %1
call %1\sd6copy CV.COM %1
call %1\sd6copy EDLIN.EXE %1 D
call %1\sd6copy JOIN.EXE %1 D
call %1\sd6copy 4201.CPI %1
call %1\sd6copy 4208.CPI %1
call %1\sd6copy 5202.CPI %1
call %1\sd6copy LCD.CPI %1
call %1\sd6copy GORILLA.BAS %1
call %1\sd6copy MONEY.BAS %1
call %1\sd6copy NIBBLES.BAS %1
call %1\sd6copy REMLINE.BAS %1
call %1\sd6copy EXE2BIN.EXE %1 D
call %1\sd6copy GRAFTABL.COM %1 D
call %1\sd6copy MIRROR.COM %1
call %1\sd6copy MSHERC.COM %1
call %1\sd6copy PRINTER.SYS %1
call %1\sd6copy PRINTFIX.COM %1
call %1\sd6copy COMMANDS.TXT %1
:copy5
if not exist %1\amjklfgh.005 goto donecopy
call %1\sd6copy CHANGEDISK 2
call %1\sd6copy NET.1XE %1
call %1\sd6copy SETNAME.EXE %1
call %1\sd6copy NETBEUI.DOS %1
call %1\sd6copy NETWKSTA.1XE %1
call %1\sd6copy NETWKSTA.2XE %1
call %1\sd6copy REDIR.1XE %1
call %1\sd6copy REDIR.2XE %1
call %1\sd6copy NET.TXT %1
:donecopy
del %1\amjklfgh.00? > NUL
del %1\sd6copy.bat > NUL
del %1\expand.exe > NUL
if exist %1\expand.999 ren %1\expand.999 expand.exe > NUL
echo ---------------------------------------
echo.
echo Finished installing the MS-DOS 6 Supplemental utilities!
echo.
echo NOTE If you installed the additional utilities from MS-DOS 5.0,
echo you cannot use the utilities until you restart your computer.
diskid0%SD6% %1
:usage
echo SETUP [drive:][path]
echo.
echo [drive:][path] - Directory to install the utilities into.
echo (ie. "C:\MSDOS", "C:").
goto done
:patherr
echo.
echo Setup was unable to create the directory %1!
echo.
echo Note: The supplied directory name must not have a trailing \. If you are
echo installing to the root directory, just specify the drive letter and
echo colon (ie. "C:").
goto done
:enverr
echo.
echo ERROR: Not enough environment space to run SETUP.BAT!
goto done
:direrr
echo.
echo ERROR: You must run SETUP.BAT from the drive and directory that contains
echo your supplemental disk files.
goto done
:done
if exist %1\amjklfgh.00? del %1\amjklfgh.00? > NUL